*! version 1.0.3   February 21 2009 Scott Merryman
*! Based on on -betafit- by Cox, Jenkins, and Buis
* version 1.0.2   December 28, 2007 Maarten L. Buis
* version 1.0.1   November 02, 2007 Scott Merryman    

program gevfit , eclass byable(recall)
        version 10.0
        syntax varlist(max=1)  [if] [in] [fw aw]  , [SCalevar(varlist numeric) SHapevar(varlist numeric) LOcationvar(varlist numeric) /// 
        Robust Cluster(varname) Level(integer $S_level) noLOG * ] 
        marksample touse 
        local y "`varlist'"
        
        local title "ML fit of GEV "
        local wtype `weight'
        local wtexp `"`exp'"'
        if "`weight'" != "" local wgt `"[`weight'`exp']"'  
                
        if "`cluster'" != "" { 
                local robust "robust"
                local clopt "cluster(`cluster')" 
        }
        
        if "`level'" != "" local level "level(`level')"
        local log = cond("`log'" == "", "noisily", "quietly") 
        
        mlopts mlopts, `options'
        global S_MLy "`y'"

        `log' ml model lf gevfit_lf (scale:`scalevar') (shape:`shapevar') (location:`locationvar') `wgt' if `touse' , /// 
                maximize  collinear title(`title') ///
                `robust'  search(on) `clopt' `level' `mlopts' `stdopts' `modopts'

        eret local cmd "gevfit"
        eret local depvar "`y'"
	
        tempname b bscale bshape bloc
        mat `b' = e(b)
        mat `bscale' = `b'[1,"scale:"] 
        local nscale = colsof(`bscale')
        
        mat `bshape' = `b'[1,"shape:"]
        local nshape = colsof(`bshape')
        
        mat `bloc' = `b'[1,"location:"]
	local nloc = colsof(`bloc')
	
        eret matrix b_scale = `bscale'
        eret matrix b_shape = `bshape'
        eret matrix b_location = `bloc'
        eret scalar length_b_scale = `nscale'
        eret scalar length_b_shape = `nshape'
        eret scalar length_b_location = `nloc'
	
        if ("`scalevar'`shapevar'`locationvar'"!="" ) {
                eret scalar nocov = 0
        }
	
        if "`scalevar'`shapevar'`locationvar'"=="" {
                tempname e              

                mat `e' = e(b)
                local scale = `e'[1,1]
                local shape = `e'[1,2]
                local location = `e'[1,3]
	
                eret scalar bscale = `scale'
                eret scalar bshape = `shape'
                eret scalar blocation = `location'
        
                eret scalar nocov = 1
	}

        Display, `level' `diopts'
        
end

program Display
        syntax [, Level(int $S_level) *]
        local diopts "`options'"
        ml display, level(`level') `diopts'
        if `level' < 10 | `level' > 99 local level = 95
end