help ie_rate
-------------------------------------------------------------------------------

Title

    ie_rate -- intrinsic estimator for age, period, cohort (APC) applications

Syntax
        ie_rate depvar [indepvars] [if] [in] [weight] [,options]

    options                    Description
    -------------------------------------------------------------------------
      irr                       eform results
      offset()                  log of exposure for rate parameterization
      scale(dev)                calculate std. errors using deviance-based
                                 mse
  
        
Description

    ie_rate computes coefficients from an APC analysis characterized by a
    design matrix that is not full rank due to the perfect linear dependence
    between age, period, and cohort. However, unlike apc_ie, ie_rate does not
    require strict linear dependence to estimate the APC model. However, it
    does require care in inputting the proper APC design matrix (described
    below).

    The dependent variable for ie_rate is assumed to be in the form of
    counts. An offset (log exposure) should be specified in order to estimate
    a rate model. If an offset is not specified, it defaults to 0 resulting
    in a standard Poisson regression. Initial values are obtained using 
    ie_reg, which is a companion routine for linear regression on the log
    rates.

    In order to obtain APC estimates normalized according to conventional
    applications (i.e., apc_ie), it is necessary that an ANOVA design matrix
    be constructed using the last factor level of each APC factor as the
    reference as shown below.

    After estimation the user may request the a display of the full set of
    ANOVA normalized estimates, including those pertaining to the reference
    categories, which are obtained using ie_norm, which is a modified version
    of Ben Jann's devcon utility with exactly the same syntax. As mentioned
    above, it is important to code the APC design with the last category as
    reference.  Additionally, the model must include a constant term.

Example code for ANOVA design coding

        qui tab age, gen(a)
        scal arow = r(r)
        qui tab period, gen(p)
        scal prow = r(r)
        qui gen cohort = period - age
        qui tab cohort, gen(c)
        scal crow = r(r) 

* construct ANOVA normalization using last category as reference

        forval i = 1/`=arow' {
                gen aC`i' = a`i' - a`=arow'
                }

        forval i = 1/`=prow' {
                gen pC`i' = p`i' - p`=prow'
                }
 
        forval i = 1/`=crow' {
                gen cC`i' = c`i' - c`=crow'
                }

Examples

APC rate model

                
    . ie_rate d aC1-aC6 pC1-pC3 cC1-cC9, offset(logn)

fully normalized solution

                
    . ie_norm, groups(aC1-aC7, pC1-pC4, cC1-cC10)

Estimation Details

    ie_rate uses a Newton-Raphson algorithm and employes the method outlined
    in Fu (2000).  Starting values are obtained from a loglinear regression
    using the empirical rates via ie_reg, which may also be used as a
    standalone program for a loglinear analysis of empirical rates.

Saved Results

ie_rate saves the following in e():

    Scalars   
      e(N)           number of cells
      e(ll)          deviance
      e(k)           number of estimated parameters
        
    Macros    
      e(depvar)      name of dependent variable

    Matrices  
      e(Coef)        1 X K vector of estimates
      e(Var)         K X K variance-covariance matrix

    Functions 
      e(sample)       marks estimation sample

References

    Wenjiang J. Fu (2000). "Ridge Estimator in Singular Design with
        Application to Age-Period-Cohort Analysis of Disease Rates,
        Communications in Statistics - Theory and Methods, 29:2, 263-278

    Daniel A. Powers (2012). "Black-White Differences in Maternal Age,
        Maternal Birth Cohort, and Period Effects on Infant Mortality in the
        U.S. (1983-2002)." Presented at the annual meetings of the Population
        Research Association of America, San Francisco, CA, May 4 2012.


Author

    Daniel A. Powers, University of Texas at Austin,
    dpowers@austin.utexas.edu

Also see