help for oparallel

Title

oparallel -- Post-estimation command for testing the parallel regression assumption.

Syntax

oparallel ,
[
score
lr
wald
wolfegould
brant
ic
asl
reps(#)
bsample
mcci[(#)]
nodots
saving(filename [, replace double every(#)])
]

Description

oparallel is a post-estimation command testing the parallel regression
assumption in a ordered logit model. By default it performs 5 tests:

a likelihood ratio test,
a score test,
a Wald test,
a Wolfe-Gould test, and
a Brant test

These tests compare a ordered logit model with the fully generalized ordered
logit model, which relaxes the parallel regression assumption on all explanatory
variables. The former is described in help ologit and the latter in
(Williams 2006). The Wolfe-Gould test is discussed in
(Wolfe and Gould 1998) and the Brant test in
(Brant 1990). The Wolfe-Gould and Brant tests are
approximate versions of the likelihood ratio and Wald test respecitvely. Instead
of estimating the models directly, they are estimated as a set of independent
logistic regressions.

Optionally, oparallel can use the bootstrap to compute the p-values for
these tests. This is done by repeatedly sampling a new dependent variable based
on the predicted probabilities of the ordered logit model. An ordered logit
model is estimated using this new dependent variable and the original and the
test statistic is computed. The distribution of these test statistics is an
estimate of the sampling distribution if the null hypothesis is true, and the
proportion of test statistics that is larger than the test statistic in the
original data is thus an estimate of the p-value
(Efron and Tibshirani 1993). This estimate can
be refined by using the number of test statistics larger than the original test
statistic plus one divided by the number of replications plus 1
(Davison and Hinkley 1997). This is the
estimate used in oparallel.

In addition, it can display the comparisons of AIC and BIC between
an ordered logit model and the fully generalized ordered logit model.

Options

Statistics

The default is to compute and display all 5 statistics. If any of the options
below is specified, then the default changes to computing and displaying only
the specified statistics.

score specifies that the score test is to be computed and displayed.

lr specifies that the likelihood ratio test is to be computed and
displayed.

wald specifies that the Wald test is to be computed and displayed.

wolfegould specifies that the Wolfe-Gould test is to be computed and
displayed.

brant specifies that the Brant test is to be computed and displayed.

Other statistics

ic specifies that the ordered logit and generalized ordered logit model
are compared using the AIC and BIC.

Bootstrap

asl specifies that the bootstrap is used to compute the p-values.

reps(#) specifies the number of replications used. The default is 999.
This means that an estimated p-value of 5% would be based on only 49
replications whose test-statistic is larger than the original test statistic. A
more reasonable number would be 19,999, that way an estimated p-value of 5% would
be based on 999 replications whose test-statistic is larger than the original
test statistic.

mcci[(#)] specifies that the Monte Carlo confidence
interval for the bootstrap estimate of the p-value is to be computed and
displayed. It quantifies the uncertainty in the estimate of the p-value due to
the randomness that is part of the bootstrap procedure. If we were to run this
bootstrap procedure many times we would expect #% of these times to return
a p-value within the Monte Carlo confidence interval. By default, # is the
default confidence level.

bsample specifies that each replication will be estimated on a sample with
replacement from the original data. By default, only the dependent variable is
drawn each replication from implied distribution of the dependent variable from
the ologit model.

nodots suppresses display of the replication dots. By default, one dot
character is displayed for each successful replication.

saving(filename [, replace double every(#)]) creates a Stata data file
(.dta file) consisting of variables containing the test statitics and p-values
for the replicates.

See prefix_saving_option for details about suboptions.

Examples

Basic use:

use "http://www.indiana.edu/~jslsoc/stata/spex_data/ordwarm2.dta", clear
ologit warm white ed prst male yr89 age
oparallel

(click to run)

The bootstrap p-values (the ASL). Here it is useful to select just one statistic
as otherwise it takes very long. The Brant statistic is usually very quick.

use "http://www.indiana.edu/~jslsoc/stata/spex_data/ordwarm2.dta", clear
ologit warm white ed prst age
oparallel, brant asl mcci

(click to run)

The distribution of the test statistics from the different bootstrap
replications is an estimate of the sampling distribution of that statistic if
the null hypothesis is true. You can save the test statistics using the
saving() option, and check if that distribution corresponds with the
theoretical distribution; a Chi-square distribution for the test statistic and
a standard uniform distribution for the p-values.

This example requires the qenv, qplot, and simpplot packages,
which can be downloaded by typing ssc install qenv, findit qplot,
and ssc install simpplot.

use "http://www.indiana.edu/~jslsoc/stata/spex_data/ordwarm2.dta", clear
ologit warm white ed prst male yr89 age
tempfile reps
oparallel, brant asl saving(`reps')
use `reps', clear

qenvchi2 Brant_stat, gen(lb ub) df(12) overall reps(5000)
tempname a b
qplot Brant_stat lb ub, ms(oh none ..) c(. l l) ///
lc(gs10 ..) legend(off) ytitle("Brant test statistic") ///
trscale(invchi2(12,@)) xtitle("{&chi}2(12) quantiles") ///
scheme(s2color) ylab(,angle(horizontal)) name(`a')

simpplot Brant_p, scheme(s2color) ylab(,angle(horizontal)) name(`b')

(click to run)

Author

Maarten L. Buis

Wissenschaftszentrum Berlin für Sozialforschung, WZB

Research unit Skill Formation and Labor Markets

maarten.buis@wzb.eu

References

Brant, Rollin (1990) Assessing proportionality in the proportional odds model
for ordinal logistic regression. Biometrics, 46(4):1171–1178.

A.C. Davison & D.V. Hinkley (1997)
Bootstrap Methods and their Application. Cambridge: Cambridge University
Press.

B. Efron & R.J. Tibshirani (1993)
An Introduction to the Bootstrap. Boca Raton: Chapman & Hall/CRC.

Williams, Richard (2006) Generalized ordered logit/partial proportional
odds models for ordinal dependent variables. The Stata Journal,
6(1): 58--82.
http://www.stata-journal.com/article.html?article=st0097

Wolfe, Rory and William Gould (1998) An approximate likelihood-ratio
test for ordinal response models. Stata Technical Bulletin,
7(42): 24--27.
http://www.stata.com/products/stb/journals/stb42.pdf

Acknowledgements

The subroutines for the Wolfe-Gould test are based on omodel version 1.0.1
by Rory Wolfe and Bill Gould, which is discussed in (Wolfe & Gould 1998)

The subroutines for the Brant test are based on brant version 1.6.0 by
J. Scott Long and Jeremy Freese, which is part of the spost package.

Richard Williams and Ariel Linden provided many helpful comments

Also see

Online: ologit, test, lrtest

If installed: omodel, brant, gologit2