/*
  pac2

  VERSION 1.0.0  21dec2002

*/

VERSION 8.0

INCLUDE graph_header

INCLUDE header

HELP hlp1, view("help pac")
RESET res1

DIALOG main, label("pac2 - Partial correlograms + confidence intervals") /*
		*/ tabtitle("Main")
BEGIN
  INCLUDE _glist_def	/* graph list definitions */
  INCLUDE g_cmdinit	// hidden checkbox

  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_tsset
  TEXT     tx_var          _lft      _top      _cwd2     .,		/*
		*/label("Variable:")
  VARNAME  vn_var          @         _ss       _vnwd     .,             /*
  		*/label("Variable")

  GROUPBOX gb_opt          @         _xls      _iwd      _ht18h,	/*
  		*/label("Options")
  GROUPBOX gb_lags         _indent   _ss       _ibwd     _ht4h,		/*
  		*/ label("Number of partial autocorrelations to compute")
  RADIO    rb_lags1        _indent   _ss       _inwd     .,             /*
*/ label("Default -- min([n/2] - 2, 40)")	/*
  		*/clickon(gaction main.sp_lags2.disable)                /*
		*/first
  RADIO    rb_lags2        @         _ms       _rbwd     .,             /*
  		*/label("")                                             /*
  		*/clickon(gaction main.sp_lags2.enable)                 /*
		*/last
  DEFINE _x @x
  SPINNER  sp_lags2        _rbsep    @         _spwd     .,        	/*
		*/label("Partial autocorrelations ")			/*
  		*/min(1)						/*
		*/max(100)						/*
		*/default(1)						/*
		*/option("lags")
  TEXT	   tx_lags2        _spsep    @         _rbspr2   .,             /*
  		*/ label("Partial autocorrelations ")

  CHECKBOX ck_gen          _ilft     _xls      _ibwd     .,		/*
  */ label("Generate a variable to hold the partial autocorrelations: (suppresses the graph)")	/*
  		*/ clickon("program graph_off")				/*
  		*/ clickoff("program graph_on")
  EDIT     ed_gen  	   _indent2  _ss       _vnwd     .,             /*
  		*/label("Variable to hold estimated partial autocorrelation")/*
  		*/max(32)						/*
  		*/option("nograph generate")

  DEFINE _x _ilft
  DEFINE _y _ls
  DEFINE _cx _sprb
  INCLUDE _sp_level

  CHECKBOX ck_srv          _ilft     _ls       _ibwd     .,             /*
  	*/ label("Include standardized residual variances in graph")	/*
  		*/ option("srv")

END

INCLUDE _glist_sc	/* graph list scripts */

SCRIPT cmdinit
BEGIN
	main.ck_cmdinit.hide
	gciopts.ck_option.seton
END

PROGRAM graph_off
BEGIN
	call gaction main.ed_gen.enable

	call script gyxview_disable
	call script gciopts_disable
	call script gr_twoway_disable
END

PROGRAM graph_on
BEGIN
	call gaction main.ed_gen.disable

	call script gyxview_enable
	call script gciopts_enable
	call script gr_twoway_enable
END

INCLUDE ifin

INCLUDE gyxview
INCLUDE gdropline_chlist
INCLUDE gciopts
INCLUDE grarea_chlist
INCLUDE gr_twoway

PROGRAM command
BEGIN
	put "pac2 "
	varlist main.vn_var
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_lags2 {
			optionarg main.sp_lags2
		}
		if main.ck_gen {
			require main.ed_gen
			optionarg main.ed_gen
		}
		INCLUDE _level_main_pr
		option main.ck_srv

		put " " /program gyxview_output
		put " " /program gciopts_output
		put " " /program gr_twoway_output

	endoptions
END