// litgov4-11  cfb 9B09
capt log close
local jobname litgov4-11
log using `jobname', replace

// bring in decision dates, merge with estimation sample database

local in1 caseinputfileDates 
local dpm = 365.25/12

insheet using `in1'.csv, names clear
tab action_type
keep if action_type == "PRI"
g dateDismissed = date(dismissal_date, "MDY")
g dateSettled = date(settlement_date, "MDY")
save `in1'.dta, replace

local ts 9408
local in2 litgov4_est3`ts'
use `in2', clear
drop if ~t56s
drop casetag cc
egen casetag = tag(case_code)  
keep if casetag
merge 1:1 case_code using `in1'
keep if _merge == 3
drop _merge

g dateFiled = date(filing_date, "MDY", 2040)
format %td date*
su date*
g timetoSettle = (dateSettled - dateFiled) / `dpm'
g timetoDismiss = (dateDismissed - dateFiled) / `dpm' 
count if !mi(timetoSettle) | !mi(timetoDismiss)
local ncase `r(N)'
l case_code if mi(timetoSettle) & mi(timetoDismiss)
su time*, detail
// within one year
g oneyrSettled = (timetoSettle <= 12)
g oneyrDismissed = (timetoDismiss <= 12)
su oneyr*

foreach v of varlist insthold sumout gindex {
	su `v', detail
	sktest `v'
}

kdensity timetoSettle, g(x1 dSettled) nogr
kdensity timetoDismiss, g(x2 dDismissed) nogr
label var x1 months
label var dSettled "Time to Settlement"
label var x2 months
label var dDismissed "Time to Dismissal"
line dSettled x1 || line dDismissed x2, scheme(s2mono) /// 
  ti("Time to decision of `ncase' SFCA lawsuits") ///
  yti(empirical density) saving(timetoDecision, replace)
graph export timetoDecision.pdf, replace
log2html `jobname', replace