// litgov4-12  cfb 0308
capt log close
set more off
local jobname litgov4-12
local basedir "/Users/baum/Documents/Chuck/    ChuckLitGov4/"
log using "`basedir'/`jobname'", replace

cd "`basedir'paper_datasets9408/IRRC_matched_input_revised9408/"
local ts 9408
local in1 dirinfo_full_long`ts'.dta
local ou1 dirinfo_full_hazard`ts'.dta

use `in1', clear
drop __*
// zap director-years for which suit_year = -1 
label drop suit_year
tab suit_year
drop if suit_year == -1
// zap director-years for which yr is missing
drop if mi(yr)
tab yr, mi
tab status_yr, mi

encode dircase, gen(idircase)
// ** DISABLE ** must drop those joining board after suit_year 0
egen mindir = min(suit_year), by(idircase)
// drop if mindir > 0
tabstat mindir, by(case_code) stat(N min max)

egen tagdir = tag(idircase)
egen maxdir = max(suit_year), by(idircase)
g nyrdir = maxdir if tagdir
tab nyrdir

sort idircase suit_year
l dircase suit_year, nolab sepby(idircase)

// check for gaps
xtset idircase suit_year
g gap = cond(suit_year > 0, D.suit_year, 0)
tab gap, mi
l dircase gap suit_year if mi(gap), sepby(dircase)
// create tag for these directors' obs
egen nobsavail = count(gap), by(dircase)
bys idircase: g dirwithgap = (nobsavail < _N)
count if tagdir
count if dirwithgap

// create departure variable if not right-censored
// now that 'joiners' are still in the sample, remove them with mindir
bys idircase: g departed = (maxdir < 4)*(_n == _N) if mindir == 0
// alternate variable without gap directors
bys idircase: g departed2 = (maxdir < 4)*(_n == _N) if !dirwithgap & mindir == 0

tab suit_year departed
tab suit_year departed2

// data should now be in order for Nigro-style analysis
// but may need additional case-specific variables merged on

// now should be able to compute change-in-CEO variable by case_code's min, max dircase values

desc
su
save "`basedir'/`ou1'", replace
log close
cd "`basedir'"
log2html "`basedir'/`jobname'", replace

set more on