// litgov4-14  cfb 0331
capt log close
set more off
local jobname litgov4-14
local basedir "/Users/baum/Documents/Chuck/    ChuckLitGov4/"
log using "`basedir'/`jobname'", replace

cd "`basedir'"
local ts 9408
local in1 pj0331_`ts'.dta
use `in1', clear

// unconditional hazard
loc ifc !mi(filingyear) filingyear<=2000 filingyear>2000
loc ifcl1 Filed 1996-2003 
loc ifcl2 Filed 1996-2000 
loc ifcl3 Filed 2001-2003
g ssyr = _n in 1/4
lab var ssyr "departed by year"
forv i=1/3 {
	loc cnd: word `i' of `ifc'
	di "`cnd'"
	tab suit_year departed if `cnd'
	su iota if `cnd' , mean
	g base`i' = r(N) in 1
	qui g dep`i' = .
	qui g emphaz`i' = .
	lab var emphaz`i' "`ifcl`i''"

	forv j=1/4 {
	su departed if suit_year == (`j' - 1) & `cnd', mean
	qui replace dep`i' = r(sum) in `j'
	qui replace emphaz`i' = dep`i' / base`i' in `j' 
	qui replace base`i' = base`i'[`j'] - dep`i'[`j'] in `=`j' + 1' 
	}
	l ssyr base`i' dep`i' emphaz`i' in 1/4
}

tw line emphaz1 emphaz2 emphaz3 ssyr in 1/4, scheme(s2mono) ///
legend(size(small)) ti("Empirical hazard rate of director departure") saving(emphaz, replace)
graph export emphaz.pdf, replace

// conditional hazard
compress suit_year settled topqsettle topqssettle
loc rhs restate gaap age entrench ceo insider stkholding 
loc rhs1 settled `rhs'
loc rhs2 topqsettle `rhs'
loc rhs3 topqssettle `rhs'

su departed departed2 `rhs' settled topqsettle topqssettle

// could also grab SEs for each of the predictive margins
forv i=1/3 {
	probit departed `rhs`i'' i.year, nolog
	margins, dydx(`rhs`i'')
	loc sv: word 1 of `rhs`i''
	margins, over(`sv' suit_year)
	mat pr_`sv'_1 = r(b)
	mat pr_`sv'_1v = r(V)

	probit departed2 `rhs`i'' i.year, nolog
	margins, dydx(`rhs`i'')
	margins, over(`sv' suit_year)
	mat pr_`sv'_2 = r(b)
	mat pr_`sv'_2v = r(V)
	
}

forv i=1/6 {
	qui g pr`i' = .
	qui g ul`i' = .
	qui g ll`i' = .
}
qui g psyr = _n - 1 in 1/5

mata: 
	st_view(pr=.,(1,5), ("pr1 pr2 pr3 pr4 pr5 pr6"), .)
	st_view(ul=.,(1,5), ("ul1 ul2 ul3 ul4 ul5 ul6"), .)
	st_view(ll=.,(1,5), ("ll1 ll2 ll3 ll4 ll5 ll6"), .)
	p12 = colshape(st_matrix("pr_settled_1"), 5)'
	p34 = colshape(st_matrix("pr_topqsettle_1"), 5)'
	p56 = colshape(st_matrix("pr_topqssettle_1"), 5)'
	pr[.,.] = p12, p34, p56
	pr
	se12 = colshape(sqrt(diagonal(st_matrix("pr_settled_1v")))', 5)'
	se34 = colshape(sqrt(diagonal(st_matrix("pr_topqsettle_1v")))', 5)'
	se56 = colshape(sqrt(diagonal(st_matrix("pr_topqssettle_1v")))', 5)'
	ul[.,.] = pr + 1.96 :* (se12, se34, se56)
	ll[.,.] = pr - 1.96 :* (se12, se34, se56)
end

l psyr pr? in 1/5, sep(0)
l psyr ul? in 1/5, sep(0)
l psyr ll? in 1/5, sep(0)
lab var psyr "Suit year"
lab var pr1 "Dismissed"
lab var pr2 "Settled"
lab var pr3 "{&lt} Q4 of settlement amount"
lab var pr4 "Q4 of settlement amount"
lab var pr5 "{&lt} Q4 of scaled settlement amount"
lab var pr6 "Q4 of scaled settlement amount"
forv i=1/6 {
	lab var ul`i' "95% c.i."
	lab var ll`i' "95% c.i."
}

tw (line pr1 pr2 psyr in 1/5, scheme(s2mono) ti("Conditional hazard rate") ///
legend(size(small))  saving(chaz1, replace)) (rline ul1 ll1 psyr) (rline ul2 ll2 psyr)
graph export chaz1.pdf, replace
tw (line pr3 pr4 psyr in 1/5, scheme(s2mono) ti("Conditional hazard rate") ///
legend(size(small)) saving(chaz2, replace)) (rline ul3 ll3 psyr) (rline ul4 ll4 psyr)
graph export chaz2.pdf, replace
tw (line pr5 pr6 psyr in 1/5, scheme(s2mono) ti("Conditional hazard rate") ///
legend(size(small)) saving(chaz3, replace)) (rline ul5 ll5 psyr) (rline ul6 ll6 psyr)
graph export chaz3.pdf, replace


log close
log2html "`basedir'/`jobname'", replace

set more on