// 327evstud2  cfb 8218
set more off
capt log close
log using 327evstud2.smcl, replace
use crspret200106, clear

// tag one obs for each company
egen comp=tag(permno)
preserve
keep if comp
keep permno
set seed 20080219
// to construct fake event-study data, pick a sample of 150 companies
// allowing for losses with date mismatch
sample 150, count
sort permno
save 327comps,replace
restore
sort permno caldt
merge permno using 327comps, uniqusing
tab _merge
// keep only obs for the companies we want
keep if _merge==3
drop _merge

// generate the fake event dates over the available IQR of dates for each firm
g long event_date = 0
g long first_date = 0
g long last_date = 0

levelsof permno, local(keys)
foreach f of local keys {
	qui su caldt if permno==`f', detail
	scalar ed = int(uniform()*(r(p75)-r(p25)))+r(p25)
	scalar ed = cond(dow(ed)>1, ed, ed+2)
	scalar ed = cond(dow(ed)<7, ed, ed-2)
	qui replace event_date = ed if permno==`f'
	qui replace first_date = r(min) if permno==`f'
	qui replace last_date = r(max) if permno==`f'
}
egen fd=tag(permno)
keep if fd
keep permno event_date first_date last_date 
su
sort permno event_date 
saveold 327event_dates, replace

log close
log2html 327evstud2.smcl, replace