*! 1.1 23Mai2000 UKohler, Univ. Mannheim
program define himatrix
	version 6.0
	syntax varlist(min=2) [if][in], Hilite(string) [HSymbol(string) B2title(string) *]

	* Declarations
	tempvar HILITE
      tempname hilab

	* if/in
	marksample touse

   	* Graph-Defaults
	if "`hsymbol'" == "" {local hsymbol "X"}
      if `"`b2title'"'=="" {
      	local b2title `"`hilite' highlighted"'
      }

	* Generate Highlight--Variable
	quietly gen `HILITE' = `hilite' if `touse'
	label value `HILITE' `hilab'
	label define `hilab' 0 "." 1 "`hsymbol'"

	* Graph
    	graph `varlist' if `touse', matrix symbol([`HILITE']) /*
                      */ b2(`"`b2title'"') `options'

end
exit