help probgenextval

Title

Performs Estimations of Binary Generalized Extreme Value (GEV) Models

Syntax

probgenextval
depvar
indepvars
[if] [in] [weight]
[, options]

Model
constraints(estimation options##constraints():constraints) apply specified linear constraints

exposure(varname:varname_e) include ln(varname_e) in model with coefficient constrained to 1

offset(varname:varname_o) include varname_o in model with coefficient constrained to 1

noconstant suppress constant term

nolrtest report the model Wald test

init specify the computation of the internal initial values

Reporting
level(#) set confidence level; default is level(95)

or odds ratio, string is Odds Ratio

SE/Robust
vce(vcetype) vcetype may be oim, robust, or opg

cluster(varname) adjust standard errors for intragroup correlation; implies vce(robust)

Max options
maximize_options control the maximization process; seldom used

indepvars may contain factor variables; see fvvarlist.

depvar and indepvars may contain time-series operators; see tsvarlist.

by is allowed with probgenextval; see [D] by for more details on by.

bootstrap, mi estimate, nestreg, rolling, statsby, stepwise, and svy are allowed; see prefix.

fweights, iweights, and pweights are allowed; see weight.

See below for features available after estimation.

Description

probgenextval performs estimations of binary generalized extreme value (GEV) models. The generalized extreme value (GEV) distribution
is a lineage of continuous probability laws that are utilized to characterize extreme values phenomena. It incorporates the Gumbel, Frechet
and Weibull distributions lineages also known as type I, II and III extreme value distributions. The generalized extreme value (GEV)
distribution, by incorporating the previous three distributions, permits to obtain a continuous spectrum of possible shapes encompassing
all the three preceding distributions. In this sense, it is more flexible because it lets the data speak and choose which distribution
is more suitable. The command probgenextval estimates a generalized extreme value (GEV) model for a binary dependent variable, typically
with one of the outcomes rare, or extremely rare, relative to the other. The command probgenextval can calculate robust and
cluster-robust standard errors and remodel results for complex survey designs. The generalized extreme value (GEV) distribution is
employed in Extreme Value Theory or Extreme Value Analysis to model the probability of events that are more extreme than any formerly
noticed. That is, it is utilized to estimate the risk of extreme, rare events, for example: the 1755 Lisbon Earthquake, the 2004 Indian
Ocean Earthquake and Tsunami, Credit Defaults, and the Modeling of COVID-19/CORONAVIRUS. The theory behind the command probgenextval
can be found in Calabrese and Osmetti (Journal of Applied Statistics, 2013), and Wang and Dey (The Annals of Applied Statistics, 2010).

Econometric Model

The estimated econometric model can be written as:

Pr(y_j = 1| x_j) = F(x_j*b) (1)

where

Pr(.) denotes Probability

y_j is the dependent variable. It is a Binary variable. That is, it can have only two possible outcomes. This means that
it is a (1/0) or (Yes/No) outcome. Typically, one of these two outcomes is rare, or is extremely rare, relative to the other

x_j indicates the vector of independent variables

F(.) is the Cumulative Distribution Function of the Generalized Extreme Value (GEV) probability law

The vector of parameters b is typically estimated by Maximum Likelihood

j indicates the jth observation

The Cumulative Distribution Function of the Generalized Extreme Value (GEV) probability law, F(.), has the following formula:

F(x_j*b) = exp{-([1 + cxi*(x_j*b)]+)^(-1/ cxi)} (2)

with

[1 + cxi*(x_j*b)]+ = Max(0, 1 + cxi*(x_j*b)) (3)

cxi is the shape parameter. It can be any Real Number

The log-likelihood function for the Generalized Extreme Value (GEV) model is:

ln(L) = \sum _ w_j*ln + \sum _ w_j*ln{1 - F(x_j*b)}

where S is the set of all observations j such that y_j = 1

F(x_j*b) is the Cumulative Distribution Function of the Generalized Extreme Value (GEV) probability law defined above

w_j denotes the optional weights

ln(L) is maximized as described in [R] Maximize

The command probgenextval supports the Huber/White/sandwich estimator of the variance and its clustered version
using vce(robust) and vce(cluster clustvar), respectively. See [P] robust for more details. The
command can also calculate the equation-level scores

The command probgenextval also supports estimation with survey data. For details on VCEs with survey data,
see Variance estimation

Options

Model

constraints(estimation options##constraints():constraints),
exposure(varname:varname_e),
offset(varname:varname_o), and
noconstant;
see estimation options.

nolrtest indicates that the model significance test should be a Wald
test instead of a likelihood-ratio test.

init specifies the computation of the internal initial values. If you want
to calculate the initial values, you indicate this, by issuing the option init. Then
the command internally computes these initial values for you.

Reporting

level(#); set confidence level; default is level(95).

or odds ratio, string is Odds Ratio.

SE/Robust

vce(vcetype); vcetype may be oim, observed information matrix (OIM);
robust, Huber/White/sandwich estimator; or opg, outer product of the gradient
(OPG) vectors. see vce_option for more details.

cluster(varname); adjust standard errors for intragroup correlation; implies vce(robust).

Max options

maximize_options:
difficult,
technique(algorithm_spec),
iterate(#),
[no]log,
trace,
gradient,
showstep,
hessian,
showtolerance,
tolerance(#),
ltolerance(#),
nrtolerance(#),
nonrtolerance;
see [R] maximize.
These options are seldom used.

Syntax for predict

predict
[type]
newvar
[if] [in]
[, statistic]

statistic

Main
pr probability of a positive outcome; the default

xb linear prediction

cxi shape parameter

stdp standard error of the linear prediction

score first derivative of the log likelihood with respect to xb

Description for predict

predict creates a new variable containing predictions such as
probabilities, linear predictions, standard errors, and equation-level scores.

Options for predict

pr, the default, calculates the probability of a positive outcome.

xb calculates the linear prediction.

cxi calculates the shape parameter. It can be any Real Number.

stdp calculates the standard error of the linear prediction.

score calculates the equation-level score, the derivative of the log
likelihood with respect to the linear prediction.

statistic

pr probability of a positive outcome; the default

xb linear prediction

cxi shape parameter

stdp not allowed with margins

score not allowed with margins

Description for margins

margins estimates margins of response for
probabilities and linear predictions.

Syntax, Description and Options for marginsplot

For the Syntax, the Description and the Options for marginsplot, please see [R] marginsplot.

Return values for probgenextval

probgenextval saves the following in e(). Note that these saved results are almost the same as those
returned by the command [R] maximize since probgenextval is fitted using [R] ml:

Scalars

e(N) number of observations; always stored

e(k) number of parameters; always stored

e(k_eq) number of equations in e(b); usually stored

e(k_eq_model) number of equations in overall model
test; usually stored

e(k_dv) number of dependent variables; usually stored

e(df_m) model degrees of freedom; always stored

e(r2_p) pseudo-R-squared; sometimes stored

e(ll) log likelihood; always stored

e(ll_0) log likelihood, constant-only model; stored when
constant-only model is fit

e(N_clust) number of clusters; stored when vce(cluster
clustvar) is specified;
see

e(chi2) chi-squared; usually stored

e(p) p-value for model test; usually stored

e(rank) rank of e(V); always stored

e(rank0) rank of e(V) for constant-only model; stored
when constant-only model is fit

e(ic) number of iterations; usually stored

e(rc) return code; usually stored

e(converged) 1 if converged, 0 otherwise; usually stored

e(k_aux) number of ancillary parameters; always saved

Macros

e(cmd) name of command; always stored

e(cmdline) command as typed; always stored

e(depvar) names of dependent variables; always stored

e(wtype) weight type; stored when weights are specified or
implied

e(wexp) weight expression; stored when weights are specified or
implied

e(title) title in estimation output; usually stored by commands using ml

e(clustvar) name of cluster variable; stored when
vce(cluster clustvar) is specified;
see

e(chi2type) Wald or LR; type of model chi-squared
test; usually stored

e(vce) vcetype specified in vce(); stored when command
allows vce()

e(vcetype) title used to label Std. Err.; sometimes stored

e(opt) type of optimization; always stored

e(which) max or min; whether optimizer is to perform
maximization or minimization; always stored

e(ml_method) type of ml method; always stored by commands
using ml

e(user) name of likelihood-evaluator program; always stored

e(technique) from technique() option; sometimes stored

e(singularHmethod) m-marquardt or hybrid; method used
when Hessian is singular; sometimes stored (1)

e(crittype) optimization criterion; always stored (1)

e(properties) estimator properties; always stored

e(predict) program used to implement predict; usually
stored

Matrices

e(b) coefficient vector; always stored

e(Cns) constraints matrix; sometimes stored

e(ilog) iteration log (up to 20 iterations); usually stored

e(gradient) gradient vector; usually stored

e(V) variance-covariance matrix of the estimators; always
stored

e(V_modelbased) model-based variance; only stored when e(V)
is robust, cluster-robust, bootstrap, or jackknife variance

Functions

e(sample) marks estimation sample; always stored

1. Type ereturn list, all to view these results; see
[P] return.

Examples

Before beginning the estimations, we use the set more off instruction to tell
Stata not to pause when displaying the output.

set more off

We illustrate the use of the command probgenextval with the dataset probgenextvalcovid.dta. This dataset
contains a sample of cross-sectional data for developed and developing countries in the World. It contains data on 187 countries
in the World on the COVID-19 Status for the year 2020. The data on the remaining variables are for the year 2019 or the
latest year of data availability (2018).

use http://fmwww.bc.edu/repec/bocode/p/probgenextvalcovid.dta, clear

Next we describe the dataset to see the definition of each variable.

describe

Some explanations on the data are in order. Our dependent variable covid19status is a binary variable indicating
whether a country is a Low COVID-19 (0) or a High COVID-19 (1) country in the year 2020. To obtain this classification
scheme we used a Latent profile model on the variables: the Number of Confirmed Cases, the Number of Death and the Number of
Recovered Cases of COVID-19 per 100000 people in the year 2020 with two classes. Please see gsem lclass options
for more details. This allows us to classify the countries in our sample as whether they are a Low COVID-19 or a High COVID-19
country for the year 2020. We observe that most of the countries classified by the Latent profile model as Low COVID-19 countries
are indeed those categorized by The news media as Low COVID-19 countries for the year 2020. Similarly, most of the countries
classified by the Latent profile model as High COVID-19 countries are indeed those categorized by The news media as
High COVID-19 countries for the year 2020. Thus, our Latent profile model does a pretty good job in the classification of
the countries. Our variable of interest pop014pctotr is Population Ages 0-14 over Total Population for the year 2019. The other
remaining numerical variables are used as control variables or filtering variables. As indicated previously, all
these variables (control variables and filtering variables) are for the years 2019 or 2018 according to
their availability.

Now, we inspect the variable covid19status to have a detailed view on its structure.

inspect covid19status

We see that the variable covid19status takes on two unique values, 0 and 1. The value 0 denotes
Low COVID-19, and 1 denotes High COVID-19. We observe that there are 138 Zeros and 49 Ones. Hence,
there are far more Zeros than Ones. Thus, there is an asymmetry in the distribution of Zeros and Ones. The
number of Ones is rare relative to the number of Zeros. Consequently, this particular example appropriately lends itself
to be modeled by the probgenextval command because: first, the dependent variable is binary, and second, one of the
outcomes is rare relative to the other. This is what we will do in the following lines of codes.

We begin by regressing the dependent variable covid19status on the variable of interest pop014pctotr and
on the control variables rconnar gcformpcr lggdppcap. Before continuing, it is important to remind the reader that
the dependent variable is measured for the year 2020, while the variable of interest is measured for the
year 2019 and the control variables are measured for the years 2019 or 2018. Hence, the variable of interest
and the control variables are predetermined compared to the dependent variable. Consequently, there is no endogeneity issues
in this model and the ones that will follow.

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap

We see that the variable pop014pctotr has a negative and statistically significant impact on the probability
of High COVID-19. This means that an increase in the Population Ages 0-14 over Total Population in a country reduces
the probability of High COVID-19. We also observe that an increase in Real Consumption over Real GDP augments the
probability of High COVID-19. This does not mean that consuming increases COVID-19. It simply says that the activity of
consuming increases the contact rate between the infected and the susceptible population, and through this, augments the
probability of infection transmission. The other control variables are not significant.

Running the same regression as above, we now show how to use the vce(robust) option with the command probgenextval.

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap, vce(robust)

Next, we study the effect of how belonging to a region in the World affects the COVID-19 Status. At the same time, we illustrate
how to use factor variables (please see fvvarlist).

We begin by tabulating the region variable.

tabulate regionwbnum

Then we estimate the effect of the factor variable i.regionwbnum by taking North America as the base level.

probgenextval covid19status pop014pctotr ib5.regionwbnum rconnar gcformpcr lggdppcap, vce(robust)

We notice that the effect of pop014pctotr on the probability of High COVID-19 is negative
and statistically significant. This means that an increase in the Population Ages 0-14 over Total Population in a country reduces the
probability of High COVID-19. We also observe that the effects of the following factor levels for the factor
variable i.regionwbnum: East Asia & Pacific, Europe & Central Asia, Latin America & Caribbean,
Middle East & North Africa, South Asia and Sub-Saharan Africa are negative and significant
compared to the base level North America. The effects of the remaining regressors are not statistically
significant.

Now, we repeat the preceding study for the Income Groups in our sample. That is, we examine the effect of how belonging
to an Income Group in the World affects the COVID-19 Status. At the same time, we illustrate how to use factor
variables (please see fvvarlist), some maximize_options and the [R] margins command.

We begin by tabulating the Income Group variable.

tabulate incomegrwbnum

Then we estimate the effect of the factor variable i.incomegrwbnum including the impact of the remaining regressors, and
add the options technique(dfp), qtolerance(0.005) and iterate(20000) for convergence purposes.

probgenextval covid19status pop014pctotr i.incomegrwbnum rconnar gcformpcr lggdppcap, vce(robust) technique(dfp) qtolerance(0.005) iterate(20000)

Finally, we employ the [R] margins command to compute the Average marginal effect of each independent variable in
our model with the option dydx(*). We add the post option to tell [R] margins to post its results in e(), in case we
might want to tabulate the estimations results for example. We also add the vce(unconditional) option because we utilized
the vce(robust) option in our previous estimation. We additionally specify the nochainrule option because probgenextval
is a community-contributed command.

margins, dydx(*) post vce(unconditional) nochainrule

We notice that the Average marginal effect of pop014pctotr on the predicted probability of High COVID-19 is negative
and statistically significant. This means that an increase in the Population Ages 0-14 over Total Population in a country reduces the
predicted probability of High COVID-19. We also observe that the Average marginal effect of the following factor level for the factor
variable i.incomegrwbnum: Lower middle income is negative and significant compared to the base level High income. The
Average marginal effects of the Real Consumption over Real GDP and Gross Capital Formation over GDP are positive and
statistically significant. As explained previously, this last result simply means that increasing the activities of consuming and investing
augment the contact rate, and through this medium, rise the chance of infection.

Let us add more regressors to our estimation equation.

probgenextval covid19status pop014pctotr hc gcformpcr lggdppcap tradepcr lglifeexpec, technique(dfp)

We see that pop014pctotr continues to have a negative and significant effect on the probability of High COVID-19. We also see that
the Human capital index has a positive and significant impact on the probability of High COVID-19. As explained previously, this
last result simply means that increasing Human capital causes Work to increase, and through this medium, this augments the
contact rate, which in turn, rises the chance of infection.

If we do not want to display the iterations log at the beginning of the regression, we type.

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap lglifeexpec, technique(dfp) nolog

Now, we show how to perform a Likelihood-ratio test that the coefficient for hc, Human capital index, is equal
to 0. At the same time, we demonstrate how to use the if qualifier (please see [U] if for more details).

We start, by running the full estimation.

probgenextval covid19status pop014pctotr hc gcformpcr lggdppcap tradepcr lglifeexpec, technique(dfp)

Then, we store the full estimation result.

estimates store full

After this, we run the restricted estimation.

probgenextval covid19status pop014pctotr gcformpcr lggdppcap tradepcr lglifeexpec if e(sample), technique(dfp)

Then, we store the restricted estimation result.

estimates store restricted

Finally, we perform the Likelihood-ratio test that the coefficient for hc is equal to 0.

lrtest full restricted

The result of the Likelihood-ratio test illustrate that the coefficient of hc is different of 0 at
the 10 percent statistical significance level.

We can perform the same test presented previously by using the command [R] nestreg, as in:

nestreg, quietly lrtable: probgenextval covid19status (pop014pctotr gcformpcr lggdppcap tradepcr lglifeexpec) (hc), technique(dfp)

We conclude from the likelihood-ratio statistic that the coefficient on hc (that is, Block 2) is significant at
the 10 percent level.

We drop all stored estimation results before continuing.

estimates clear

In the following estimation, we examine if the Logarithm of International Tourism Number of Arrivals, lgintertourism, have an
effect on the probability of High COVID-19. At the same time, we show how to perform a Wald test after the
command probgenextval.

First, we reload our examples dataset we described above.

use http://fmwww.bc.edu/repec/bocode/p/probgenextvalcovid.dta, clear

Second, we run the following regression by including lgintertourism as a regressor.

probgenextval covid19status pop014pctotr hc rconnar tradepcr lgintertourism

We see that lgintertourism has no effect on the probability of High COVID-19. But next, we perform a Joint test that
the coefficients on pop014pctotr, hc, rconnar and lgintertourism are equal to 0.

test pop014pctotr hc rconnar lgintertourism

We observe that the four variables taken together are jointly different from 0.

Now, we demonstrate how to employ constraints (please see [R] constraint) with the command probgenextval.

We start by constraining the shape parameter cxi to be equal to 0.5.

constraint define 1 _b[/cxi]=0.5

Then, we run the following regression by specifying the option constraints(1).

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap domcredpspcr, constraints(1)

We see that constraining the shape parameter cxi to be 0.5, in order to get
a Positively Skewed Generalized Extreme Value (GEV) Distribution, does not alter our main finding. That is, an increase in
the Population Ages 0-14 over Total Population in a country reduces the probability of High COVID-19. However, we notice
that Gross Capital Formation over GDP becomes significant and gets a positive impact, like that
of Real Consumption over Real GDP. As explained previously, these last two results simply mean that
increasing the activities of consuming and investing augment the contact rate, and through this medium, rise
the chance of infection.

Before continuing, we drop all the constraints we created previously.

constraint drop _all

We reload our examples dataset we described above before continuing.

use http://fmwww.bc.edu/repec/bocode/p/probgenextvalcovid.dta, clear

We exhibit how to employ the command probgenextval with the [D] by prefix. First, we
tabulate by the development level of the countries.

tabulate developedco

Then, we sort the dataset by the development level of the countries.

sort developedco

Finally, we use the command probgenextval with the [D] by prefix.

by developedco: probgenextval covid19status pop014pctotr hc rconnar tradepcr, technique(dfp) difficult tolerance(0.5) ltolerance(0.5) nrtolerance(0.5) vce(robust) nolog

We restore the original ordering of the dataset before continuing.

sort pbm

We reload our examples dataset we described above before continuing.

use http://fmwww.bc.edu/repec/bocode/p/probgenextvalcovid.dta, clear

If we want to specify the computation of the internal initial values, we type.

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap, vce(robust) init iterate(20000)

Note that specifying the init option, could in some cases, help us
to maximize the likelihood function quickly when we are having convergence problems.

In the previous equation, we notice that, the Logarithm of GDP per Capita Constant 2010 USD has a positive and significant
impact on the probability of High COVID-19. An explanation could be that, when Real GDP per Capita augments, work and economic activity
become higher. This could in turn augment the contact rate, and through these means, rise the chance of infection when Real GDP per Capita
becomes higher.

Next, we estimate an equation with a 90% confidence interval. At the same time, we investigate
if Institutions, here Democracy, have an impact on the probability of High COVID-19.

probgenextval covid19status pop014pctotr hc gcformpcr lggdppcap tradepcr lglifeexpec democrataccc, vce(robust) init technique(bfgs) level(90)

We observe that, Democratic Accountability has a positive and significant effect on the probability of High COVID-19. A first
explanation could be that in democracies, governments are less inclined to establish draconian measures of COVID-19 lockdowns for fear of
retaliations from the electorate compared to autocratic governments. This could in turn augment the contact rate, and through this
medium, rise the chance of infection in democracies. A second explanation could be that, in most democracies, work, economic activity and
extra-activities are higher. This could in turn augment the contact rate, and through these means, rise the chance of infection in
democracies.

If we do not want to have a constant, we type.

probgenextval covid19status pop014pctotr hc gcformpcr lggdppcap tradepcr lglifeexpec democrataccc, vce(robust) init nocons

We now illustrate how to use the command probgenextval with the predict command.

We start by running the following regression.

probgenextval covid19status pop014pctotr rconnar gcformpcr lggdppcap domcredpspcr

We calculate the probability of a positive outcome.

predict double prpred, pr

We calculate the linear prediction.

predict double xbpred, xb

We calculate the shape parameter.

predict double cxipred, cxi

We calculate the standard error of the linear prediction.

predict double stdppred, stdp

We calculate the equation-level score, the derivative of the log
likelihood with respect to the linear prediction.

predict double sc*, score

We describe all the previously created variables to see their labels.

describe prpred xbpred cxipred stdppred sc1 sc2

We summarize these variables.

summarize prpred xbpred cxipred stdppred sc1 sc2, separator(0)

In the remaining examples of this section, we will demonstrate an extensive use of the command probgenextval with the
commands [R] margins and [R] marginsplot.

We begin by reloading our examples dataset we described above.

use http://fmwww.bc.edu/repec/bocode/p/probgenextvalcovid.dta, clear

Now, we run the following regression.

probgenextval covid19status pop014pctotr democrataccc hc gcformpcr lggdppcap tradepcr lglifeexpec, vce(robust) init

Then, we compute the Conditional marginal effects of each independent variable in our model, setting all variables to
their means with the option atmeans.

margins, dydx(*) post atmeans vce(unconditional) nochainrule

We notice that the Conditional marginal effect of pop014pctotr on the predicted probability of High COVID-19 is negative
and statistically significant. This means that an increase in the Population Ages 0-14 over Total Population in a country reduces the
predicted probability of High COVID-19. We also observe that the Conditional marginal effects of the following
variables: democrataccc and gcformpcr are positive and significant. The Conditional marginal effects of the remaining
regressors are not statistically significant. The results found in this table illustrate that, using Conditional marginal effects does
not change our main finding. That is, an increase in the Population Ages 0-14 over Total Population in a country reduces the
predicted probability of High COVID-19.

Next, we investigate how an older population affects the probability of High COVID-19. At the same time, we show how
to use elasticities with [R] margins.

probgenextval covid19status pop65abpctotr hc rconnar, iterate(20000)

We calculate the elasticity of each independent variable in our model with the option eyex(*).

margins, eyex(*) post nochainrule

We see that the variable pop65abpctotr has a positive and statistically significant impact on the predicted probability
of High COVID-19. This means that an increase in Population Ages 65 Above over Total Population in a country augments the
predicted probability of High COVID-19.

Let us examine if pop014pctotr is still significant if we control for pop65abpctotr.

probgenextval covid19status pop014pctotr pop65abpctotr hc rconnar

We calculate the elasticity of each independent variable in the previous model with the option eyex(*).

margins, eyex(*) post nochainrule

We notice that, an increase in Population Ages 0-14 over Total Population in a country continues to reduce the predicted
probability of High COVID-19 even after controlling for Population Ages 65 Above over Total Population.

Now, we show how to use Marginal Effects at Representative Values with the at(atspec) option. Thus, we run
the following regression.

probgenextval covid19status pop014pctotr pop65abpctotr hc rconnar

We compute the Average marginal effects of pop014pctotr at Representative Values of pop65abpctotr: 25th
Percentile (p25), 50th Percentile (p50) and 75th Percentile (p75).

margins, dydx(pop014pctotr) at((p25) pop65abpctotr) at((p50) pop65abpctotr) at((p75) pop65abpctotr) nochainrule

We see that the Average marginal effects of pop014pctotr are approximately equal to -2 no matter the values
taken by pop65abpctotr. Hence, we conclude that the effects of pop014pctotr do not differ greatly by the values taken
by pop65abpctotr.

To finish this Examples section, we now illustrate how to use the command probgenextval with
the [R] marginsplot command. We start by summarizing the variable pop014pctotr to see its range.

summarize pop014pctotr

Then, we estimate a model in which we examine if there exists a quadratic effect for the variable pop014pctotr. For this, we
specify interactions of factor variables using the pop014pctotr variable. Please see fvvarlist for more
details.

`"probgenextval covid19status c.pop014pctotr c.pop014pctotr#c.pop014pctotr rconnar gcformpcr lggdppcap, vce(robust) iterate(20000)"'

Now, we compute the Average marginal effects of pop014pctotr for pop014pctotr ranging from 0.13
to 0.48 in 0.03 increments.

margins, dydx(pop014pctotr) at(pop014pctotr=(0.13(0.03)0.48)) vce(unconditional) nochainrule

Finally, we use the [R] marginsplot command with the options recast(line), recastci(rarea) and yline(0) to
display the Average marginal effects as a line, the confidence interval as a shaded region and add a horizontal line at the
value 0 respectively.

marginsplot, recast(line) recastci(rarea) yline(0)

From this graphic, we observe that the Average marginal effects of pop014pctotr on the predicted probability
of High COVID-19 are negative and statistically significant for pop014pctotr ranging from 0.13 to 0.31. But
for pop014pctotr ranging from 0.34 to 0.46, the Average marginal effects of pop014pctotr are not
different from 0.

In writing this Examples section, we had two goals. The first, was to show how to effectively use the
command probgenextval through simple and clear examples. The second, was to undertake an original study on
the COVID-19/CORONAVIRUS and contribute to this literature. But, despite our efforts, we have only scratched the
surface of what can be done with the command probgenextval, the accompanying dataset, and the use of the
command probgenextval in conjunction with the commands [R] margins, [R] marginsplot,
[R] lrtest, [R] test or other Stata commands. We leave these avenues of research to
the reader/user to explore at her/his will!

Citation

The command probgenextval is not an Official Stata command. Like a paper, it is a free contribution to the research
community. If you find the command probgenextval and its accompanying dataset useful and utilize them in your works, please cite
them like a paper as it is explained in the Suggested Citation section of the IDEAS/RePEc webpage of the
command. Many thanks, in advance, for doing that! Please, note that citing the command probgenextval is a good way
to disseminate its use and its discovery by other researchers. Doing this, could also, potentially, help us, as a community, to
overcome COVID-19 and to help in solving other challenging current problems and those that lie ahead in the future.

References

Calabrese Raffaella and Osmetti Silvia Angela: 2013,
"Modelling Small and Medium Enterprise Loan Defaults as Rare Events: The Generalized Extreme Value Regression Model",
Journal of Applied Statistics 40(6), 1172-1188.

Wang Xia and Dey Dipak K.: 2010,
"Generalized Extreme Value Regression for Binary Response Data: An Application to B2B Electronic Payments System Adoption",
The Annals of Applied Statistics 4(4), 2000-2023.

Author

Diallo Ibrahima Amadou

FERDI (Fondation pour les Etudes et Recherches sur le Developpement International)

63 Boulevard Francois Mitterrand

63000 Clermont-Ferrand

France

E-Mail: zavren@gmail.com

Also see

Online: help for [R] cloglog, [R] probit, [R] logit, [R] Maximize,
extreme (if installed), gevfit (if installed), gumbelfit (if installed), gevd (if installed)